EP3C120 u-boot env script

echo Setting up Default EP3C120 board Environment
setenv autoload no
setenv autostart no

echo Setting flash address variables
setenv fpga_page_cur 0xC3500000
setenv fpga_page0 0xC3500000
setenv fpga_page1 0xC3880000
setenv fpga_page2 0xC3C00000
setenv uImage_cur 0xC2900000
setenv u-boot 0xC2800000
setenv uImage0 0xC2900000
setenv uImage1 0xC2D00000
setenv uImage2 0xC3100000
setenv ethernet_option_bits 0xC3FC0000
setenv option_bits 0xC3FE0000
setenv filesystem 0xC0000000

echo Setting ipaddress command

setenv ipaddr_cmd 'echo Getting ethaddr from flash; if altera ethaddr;then echo Got ethaddr; else setenv ethaddr 00:07:11:01:02:03; fi; echo DHCP Address; dhcp; run set_serverip'

setenv tftp_bootcmd 'echo TFTP Boot; run ipaddr_cmd; tftp ${loadaddr} ${serverip}:${bootfile}; setenv uImage_cur ${fileaddr}; run bootargs_cur; bootm ${uImage_cur}'

setenv uImage_bootcmd 'echo Flash Boot; run bootargs_cur;  bootm ${uImage_cur}'

setenv jffs_bootcmd 'echo JFFS Boot; mtdparts default; sysid; setenv bootfile /boot/${sysid}.img; fsload ${loadaddr} ${bootfile}; setenv uImage_cur ${fileaddr}; run bootargs_cur; bootm ${uImage_cur}'

setenv tftp_program_flash 'echo TFTP Program Flash; run ipaddr_cmd; tftp 0xF1000000 ${serverip}:tftp_program_flash_script.img; iminfo ${fileaddr}; autoscr ${fileaddr}'

setenv update_fpga_image 'echo Update FPGA Image; run ipaddr_cmd; protect off ${fpga_page_cur} +0x37FFFF; erase ${fpga_page_cur} +0x37FFFF; tftp ${loadaddr} ${serverip}:fpga_image.rbf; cp.b ${fileaddr} ${fpga_page_cur} ${filesize}'

setenv update_uImage 'echo Update uImage; run ipaddr_cmd; protect off ${uImage_cur} +0x3FFFFF; erase ${uImage_cur} +0x3FFFFF; tftp ${loadaddr} ${serverip}:uImage.img; cp.b ${fileaddr} ${uImage_cur} ${filesize}; iminfo ${fileaddr}'

setenv update_uboot 'echo Update Uboot; run ipaddr_cmd; protect off 0xC2800000 0xC28FFFFF; erase 0xC2800000 0xC28FFFFF; tftp ${loadaddr} ${serverip}:u-boot.bin; cp.b ${fileaddr} 0xC2800000 ${filesize}'

setenv update_filesystem 'echo Update Filesystem; run ipaddr_cmd; protect off ${filesystem} +0x27FFFFF; erase ${filesystem} +0x27FFFFF; tftp ${loadaddr} ${serverip}:filesystem.jffs2; cp.b ${fileaddr} ${filesystem} ${filesize}'

setenv tftpserverip ${serverip}
setenv nfsserverip ${serverip}
setenv bootfile uImage.img

setenv bootargs_jffs 'setenv bootargs noinitrd ip=dhcp rw root=/dev/mtdblock0 rootfstype=jffs2 console=ttyJ0 tsemac0=${ethaddr}'

setenv bootargs_nfs 'setenv bootargs noinitrd ip=dhcp rw root=/dev/nfs nfsroot=${nfsserverip}:${nfsroot} console=ttyJ0 tsemac0=${ethaddr}'

setenv bootargs_cur run bootargs_jffs
setenv nfsroot /data/nfsroot
setenv set_serverip 'setenv serverip ${tftpserverip}'

saveenv
